archiver/flake.nix at master · Assistant/archiver · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
{
  description = "Tool to easily archive streams with chat and metadata.";

  inputs.nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";

  outputs = { self, nixpkgs }:
    let
      extraPrograms = [ "twitch_downloader" "format" ];
      forAllSystems = nixpkgs.lib.genAttrs [
        "aarch64-linux"
        "x86_64-linux"
        "aarch64-darwin"
        "x86_64-darwin"
      ];
      config = {
        permittedInsecurePackages = [
          "dotnet-runtime-6.0.36"
          "dotnet-runtime-wrapped-6.0.36"
          "dotnet-sdk-6.0.136"
          "dotnet-sdk-wrapped-6.0.136"
        ];
      };
      packageName = (builtins.fromTOML (builtins.readFile ./Cargo.toml)).package.name;
      overlays = [ self.overlays.default ];
      liftPackages = pkgs: nixpkgs.lib.foldl'
        (acc: x: acc // { "${x}" = pkgs.${x}; })
        { default = pkgs.${packageName}; }
        extraPrograms;
      liftOverlays = pkgs: nixpkgs.lib.foldl'
        (acc: x: acc // { "${x}" = pkgs.callPackage nix/${x}.nix { }; })
        { ${packageName} = pkgs.callPackage ./package.nix { }; }
        extraPrograms;
    in
    {

      overlays.default = final: prev: liftOverlays final;

      packages = forAllSystems (system:
        let pkgs = import ./nixpkgs.nix { inherit system overlays config; };
        in liftPackages pkgs
      );
      legacyPackages = self.packages;

      checks = forAllSystems (system:
        let pkgs = import ./nixpkgs.nix { inherit system overlays config; };
        in import nix/checks.nix { inherit pkgs; }
      );

      apps = forAllSystems (system:
        let pkgs = import ./nixpkgs.nix { inherit system overlays config; };
        in import nix/apps.nix { inherit pkgs; }
      );

      devShells = forAllSystems (system:
        let pkgs = import ./nixpkgs.nix { inherit system overlays config; };
        in import ./shell.nix { inherit pkgs; }
      );

    };
}