windows support

[DetachHead]

A .ps1 or .bat version of the script would be great for people like me who are unfortunately forced to use windows at work.

Alternatively, if you prefer to only have to commit one wrapper script, the existing script could be converted to a polyglot script like what gg.cmd does

[DetachHead]

i see in the readme that windows is supposed to be supported but since it's just only a bash script i assume it's supposed to work with git bash, but that doesn't seem to be the case:

$ ./uv --version
bash: ./uv: cannot execute binary file: Exec format error

i'm on windows 11 23h2 x64, not sure if that's relevant

[FloGa]

Hi! Thank you for trying out my wrapper!

I hear you and feel your pain of being forced to use Windows at work. 😅
However, to maintain two separate scripts to serve the same purpose feels not right to me. I specifically chose Bash because it can be used on Linux and Windows (via Git Bash) equally. Usually, for my coworkers, I also provide a small bat file that searches for the Git executable on the system and calls the Bash executable from the same folder to run the actual script.

As for your problem, I don't see why it wouldn't work, because I'm also using the wrapper on Windows. Are you inside the Git Bash shell when you start the wrapper? I saw on several systems that when you are not specifically calling it via Git Bash, it would instead be executed via the first bash executable found in the system, which could actually be a symlink to Ubuntu WSL.

Please delete the .uv folder (in case the wrong binary has been downloaded) and try to start the wrapper inside a Git Bash shell. Or call it as an argument to the full path to the bash.exe from your Git installation.

[FloGa]

Another thing that comes to my mind, looking at your error message: Maybe there is a problem when you copied the contents of the wrapper? Did you do it manually with copy and paste via a Windows editor? Then maybe you ended up with an UTF-16 file that is not recognized by Bash anymore. Make sure it is a plain UTF-8 file, LF line endings, instead of CRLF.

[DetachHead]

hmm it looks like the issue is that i downloaded the script with powershell and executed it with git bash, which resulted in the script having CRLF line endings instead of LF. thanks!

i do think the readme could probably be updated to clarify that cmd and powersell are not supported

[DetachHead]

fyi as a workaround in my project i added an uv.ps1 script:

. "$env:localappdata\Programs\Git\bin\bash.exe" ./uv @args

but this only works if you know that everyone in your team has git installed to the same spot

[FloGa]

These two files are what I use in my Windows teams. Not sure if it makes sense to publish them in this repository, it might strain the topic a bit too much, what do you think?

bash.bat

Helper to find and execute the bash.exe from Git-for-Windows.

@echo off

rem This script can be used to call a Bash script with git-bash. On some
rem Windows systems, "bash" refers to the Ubuntu WSL, which is not what we
rem want here. Instead, we are searching for the "git" executable and call the
rem "bash" executable in the same folder.
rem
rem It can be called like this: .\bash.bat .\build.sh

rem Required for !-syntax
setlocal enabledelayedexpansion

rem Find the path to the git executable
for /f "delims=" %%i in ('where git') do (
    rem Store the path of the first found git executable
    set git_path=%%i
)

rem If git was found
if defined git_path (
    rem Extract the directory of git
    for %%j in ("!git_path!") do (
        set git_dir=%%~dpj
    )

    rem Build the path to the bash executable. Since git can be found in bin
    rem or in cmd directory, we need to explicitly go up and use the bin
    rem directory, since bash only resides there.
    set bash_path=!git_dir!..\bin\bash.exe

    rem Check if the bash executable exists
    if exist "!bash_path!" (
        "!bash_path!" %*
    ) else (
        echo bash executable was not found in directory: !git_dir!
    )
) else (
    echo git executable was not found.
)

endlocal

uv.bat

Tiny wrapper to call bash.bat uv. (Literally it means: Execute the bash.bat in the same folder as this wrapper, and call it with the wrapper's path, without an extension, so uv.bat becomes uv.)

@call "%~dp0bash.bat" "%~dp0%~n0" %*

[DetachHead]

yeah a .bat or .ps1 script that can automatically find and execute git bash would be nice. an alternative approach could be a polyglot script like what gg.cmd does:

: <<BATCH
    @echo off
    : VERSION: 166
    set GG_CMD_PATH=%~f0
    if not defined GG_CACHE_DIR (
        if "%1"=="-l" (
            set GG_CACHE_DIR=.cache\gg
            shift /1
        ) else (
            set GG_CACHE_DIR=%UserProfile%\.cache\gg
        )
    ) else (
        if "%1"=="-l" shift /1
    )
    if exist "%GG_CACHE_DIR%\gg-166\stage2.ps1" (
        powershell -executionpolicy bypass -file "%GG_CACHE_DIR%\gg-166\stage2.ps1" %*
        exit /b %errorlevel%
    )
    if not exist "%GG_CACHE_DIR%" mkdir "%GG_CACHE_DIR%"
    powershell -c "sc m2 ([byte[]](gc '%0' -Encoding Byte | select -Skip 1425)) -Encoding Byte"
    tar -zxf m2 -C "%GG_CACHE_DIR%"
    del m2
    powershell -executionpolicy bypass -file "%GG_CACHE_DIR%\gg-166\stage2.ps1" %*
    exit /b %errorlevel%
BATCH
if command -v realpath >/dev/null 2>&1; then
  export GG_CMD_PATH="$(realpath -s "$0" 2>/dev/null || readlink -f "$0" 2>/dev/null || echo "$0")"
else
  export GG_CMD_PATH="$0"
fi

if [ -z "$GG_CACHE_DIR" ]; then
  if [ "$1" = "-l" ]; then
    export GG_CACHE_DIR=".cache/gg"
    shift
  else
    export GG_CACHE_DIR="$HOME/.cache/gg"
  fi
elif [ "$1" = "-l" ]; then
  shift
fi

if [ -f "$GG_CACHE_DIR/gg-166/stage2.sh" ]; then
  "$GG_CACHE_DIR/gg-166/stage2.sh" "$@"
  exit
fi

mkdir -p "$GG_CACHE_DIR"
tail -c +1426 "$0" | tar -zpx -C "$GG_CACHE_DIR" && "$GG_CACHE_DIR/gg-166/stage2.sh" "$@"
exit

this way, only one wrapper script ever needs to be committed and it works on all operating systems regardless of the shell

[FloGa]

I see two things fundamentally wrong with this polyglot approach of gg.cmd:

1. The functionality has to be implemented several times in different scripting languages. This is highly risky, because you have to make absolutely sure that all variations of the functionality behave exactly the same in all circumsstances. This is a non-trivial task that is probably not even doable reliably.
2. The file type is non-deterministic anymore. On Windows, the file type is usually determined by the file extension, and in Linux the first line (Shebang) is used to select the interpreter. Even if the Shebang can be ignored by the "non-Bash" part of the script (for example PowerShell, which also uses # as comment marker), it would still kind of "lie" about the actual file type. And what about Windows? You would need to name the file uv.ps1 so it can be executed properly without calling the interpreter explicitly. And then your Linux users will be stuck with a PS1 file which is actually a Bash script in disguise.

No, polyglot is a nasty hack in my eyes. I'd rather try to create a wrapper as a Batch script, that will in turn call the Bash script with the correct Bash executable, like I'm doing in my work projects with my team members. I will put together something and let you know, so you can try it out if you're interested! 😊

[FloGa]

(Opening the issue again, since we have an on-going discussion here.)

[DetachHead]

Fair enough, polyglot scripts are a fun hack but they are definitely a hack lol

[FloGa]

Alright, I re-furbished my bat-to-bash wrapper and included it alongside the Bash script. The intention now is to have both the DosBatch script as well as the Bash script in the repo, to satisfy both Linux and Windows users. I remember Maven had it too, I always had mvnw and mvnw.bat in my Java projects.

As explained above, the uv.bat does not actually do anything itself:

• It searches all git executables available in the PATH.
• It looks for a bash.exe in the same directory as git.exe (or more correctly, it goes up a directory and from there looks for bin\bash.exe; I tested this with several of my co-workers and each one of them had Git installed in a different way it seems ...).
• If bash.exe is found, call it with .\uv and the rest of the command line arguments.

So, the real logic is stil in the Bash script, the DosBatch script merely looks for a way to execute the Bash script.

Now I need your help, @DetachHead! Can you try this Batch script and see if it also works on your machine? Save it as uv.bat in the same folder as uv and try it like .\uv.bat --version. That would be a great help before I merge it in!

You can find it on the respective feature branch: https://github.com/FloGa/uv-wrapper/blob/feature/bat-wrapper/uv.bat