flake.nix

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    rust-overlay.url = "github:oxalica/rust-overlay";
  };

  outputs = inputs:
    inputs.flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [ "x86_64-linux" ];
      perSystem = { config, self', pkgs, lib, system, ... }:
        let
		  # Libraries
          runtimeDeps = with pkgs; [ openssl postgresql.lib ];

		  # Compilers & linkers & dependecy finding programs
          buildDeps = with pkgs; [ pkg-config ];

		  # Host/target agnostic programs
          devDeps = with pkgs; [ postgresql diesel-cli pgweb ];

          cargoToml = builtins.fromTOML (builtins.readFile ./Cargo.toml);
          msrv = cargoToml.package.rust-version;

          rustPackage = features:
            (pkgs.makeRustPlatform {
              cargo = pkgs.rust-bin.stable.latest.minimal;
              rustc = pkgs.rust-bin.stable.latest.minimal;
            }).buildRustPackage {
              inherit (cargoToml.package) name version;
              src = ./.;
              cargoLock.lockFile = ./Cargo.lock;
              buildFeatures = features;
              buildInputs = runtimeDeps;
              nativeBuildInputs = buildDeps;
              doCheck = false;
            };

          mkDevShell = rustc:
            pkgs.mkShell {
              shellHook = ''
                export RUST_SRC_PATH=${pkgs.rustPlatform.rustLibSrc}

				export NIX_DEV_SHELL_TMP="/tmp/nix-d-she-rpsinapi"

				mkdir -p "$NIX_DEV_SHELL_TMP"

				# See .example.env
				export ENCRYPTION_KEY=$(openssl rand -base64 24 | tr -d "\n")
				export ROCKET_SECRET_KEY=$(openssl rand -base64 64 | tr -d "\n")

				# Dev database	
				export PGDATA="$NIX_DEV_SHELL_TMP/pg-dev-data"
    			export PGPORT=5432
    			export PGHOST=localhost
    			export PGUSER=$USER
    			export PGPASSWORD=$USER

				db_name=roops-dev

				export DATABASE_URL="postgres://$PGUSER:$PGPASSWORD@$PGHOST:$PGPORT/$db_name"
				export ROCKET_DATABASES="{roops={url=\"$DATABASE_URL\"}}"
				export PGWEB_DATABASE_URL=$DATABASE_URL?sslmode=disable

				function start_dev_db {
					pg_ctl -D "$PGDATA" -l "$PGDATA/logfile" start
				}

				function stop_dev_db {
					pg_ctl -D "$PGDATA" -l "$PGDATA/logfile" stop
				}

				function delete_dev_db {
					stop_dev_db

					rm -rf "$PGDATA"
				}

				function init_dev_db {
					delete_dev_db

    				mkdir "$PGDATA"
    				initdb -D "$PGDATA"

					mkdir "$PGDATA/unix-sockets"
					echo "unix_socket_directories = '$PGDATA/unix-sockets'" >> "$PGDATA/postgresql.conf"

					start_dev_db

    				createdb $db_name

					stop_dev_db
				}

				trap "delete_dev_db" EXIT
				'';
              buildInputs = runtimeDeps;
              nativeBuildInputs = buildDeps ++ devDeps ++ [ rustc ];
            };
        in {
          _module.args.pkgs = import inputs.nixpkgs {
            inherit system;
            overlays = [ (import inputs.rust-overlay) ];
          };

          packages.default = self'.packages.roops-internal-api;
          devShells.default = self'.devShells.stable;

          packages.roops-internal-api = (rustPackage "");

          devShells.stable = (mkDevShell pkgs.rust-bin.stable.latest.default);
          devShells.msrv = (mkDevShell pkgs.rust-bin.stable.${msrv}.default);
        };
    };
}