static-data/build.gradle at master · StaticStudios/static-data · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
plugins {
    id 'java'
}

allprojects {
    group = 'net.staticstudios'
    version = '3.3.10-SNAPSHOT'

    repositories {
        mavenCentral()
        maven {
            name = "StaticStudios"
            url = "https://repo.staticstudios.net/snapshots/"
        }
    }

    java {
        targetCompatibility = JavaVersion.VERSION_21
        sourceCompatibility = JavaVersion.VERSION_21
        toolchain {
            languageVersion = JavaLanguageVersion.of(21)
        }
    }
}

subprojects {
    plugins.withId('maven-publish') {
        publishing {
            repositories {
                maven {
                    credentials(org.gradle.api.credentials.PasswordCredentials.class)
                    name = "StaticStudios"
                    var base = "https://repo.staticstudios.net"
                    var releasesRepoUrl = "$base/releases/"
                    var snapshotsRepoUrl = "$base/snapshots/"
                    setUrl((version.toString().endsWith("SNAPSHOT")) ? snapshotsRepoUrl : releasesRepoUrl)
                }
            }
        }

        rootProject.tasks.named("publish").configure {
            dependsOn(tasks.named("publish"))
        }

        rootProject.tasks.named("publishToMavenLocal").configure {
            dependsOn(tasks.named("publishToMavenLocal"))
        }
    }
}

tasks.register("publish") {
    group = "publishing"
    description = "Publishes all modules to the StaticStudios Maven repository."
}

tasks.register("publishToMavenLocal") {
    group = "publishing"
    description = "Publishes all modules to Maven Local."
}