GenericWizard/build.gradle at master · TrackerSB/GenericWizard · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
plugins {
    id "java-library"
    id "org.openjfx.javafxplugin" version "0.0.10"
    id "maven-publish"
    id "signing"
}

group "bayern.steinbrecher"
version "1.61-rc.21-SNAPSHOT"

repositories {
    mavenCentral()
    maven {
        url "https://oss.sonatype.org/content/repositories/snapshots"
    }
}

sourceCompatibility = 19
targetCompatibility = 19

dependencies {
    compileOnly 'org.jetbrains:annotations:24.0.0'
    implementation "bayern.steinbrecher:JavaUtility:0.19-rc.2-SNAPSHOT"
    implementation 'com.google.guava:guava:31.1-jre'
}

compileJava.options.encoding = 'UTF-8'

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

plugins.withType(JavaPlugin).configureEach {
    java {
        modularity.inferModulePath = true
        withSourcesJar()
        withJavadocJar()
    }
}

javafx {
    version = "$sourceCompatibility"
    modules = [
            "javafx.controls",
            "javafx.fxml",
            "javafx.graphics"
    ]
}

javadoc {
    if(JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}

publishing {
    repositories {
        maven {
            name = "OSSRH"
            def releasesRepoUrl = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
            def snapshotsRepoUrl = "https://oss.sonatype.org/content/repositories/snapshots/"
            url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
            credentials {
                username = "${ossrhUsername}"
                password = "${ossrhPassword}"
            }
        }
    }
    publications {
        library(MavenPublication) {
            pom {
                name = 'GenericWizard'
                description = 'A generalized, flexible, reusable and dynamic wizard implementation for JavaFX.'
                url = 'https://www.steinbrecher.bayern/projects/mavenPackages.html#genericWizard'
                licenses {
                    license {
                        name = 'GPL-3.0'
                    }
                }
                developers {
                    developer {
                        id = 'stefanHuber'
                        name = 'Stefan Huber'
                        email = 'stefan.huber.niedling@outlook.com'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/TrackerSB/GenericWizard.git'
                    developerConnection = 'scm:git:ssh://github.com/TrackerSB/GenericWizard.git'
                    url = 'https://github.com/TrackerSB/GenericWizard'
                }
            }
            from components.java
        }
    }
}

signing {
    useGpgCmd()
    sign publishing.publications.library
}