ScreenSwitcher/build.gradle at master · TrackerSB/ScreenSwitcher · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
plugins {
    id "java-library"
    id "org.openjfx.javafxplugin" version '0.0.10'
    id "maven-publish"
    id "signing"
}

group "bayern.steinbrecher"
version "0.2.5-rc.3-SNAPSHOT"

repositories {
    mavenCentral()
    maven {
        url "https://oss.sonatype.org/content/repositories/snapshots"
    }
}

dependencies {
    implementation "bayern.steinbrecher:JavaUtility:0.19-rc.2-SNAPSHOT"
    implementation 'bayern.steinbrecher:GenericWizard:1.61-rc.20-SNAPSHOT'
    compileOnly 'org.jetbrains:annotations:24.0.0'
}

sourceCompatibility = 19
targetCompatibility = 19

compileJava.options.encoding = 'UTF-8'

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

plugins.withType(JavaPlugin).configureEach {
    java {
        modularity.inferModulePath = true
        withSourcesJar()
        withJavadocJar()
    }
}

javafx {
    version = "$sourceCompatibility"
    modules = ["javafx.controls", "javafx.fxml", "javafx.graphics"]
}

javadoc {
    if(JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}

publishing {
    repositories {
        maven {
            name = "OSSRH"
            def releasesRepoUrl = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
            def snapshotsRepoUrl = "https://oss.sonatype.org/content/repositories/snapshots/"
            url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
            credentials {
                username = "${ossrhUsername}"
                password = "${ossrhPassword}"
            }
        }
    }
    publications {
        mavenScreenSwitcher(MavenPublication) {
            pom {
                name = 'ScreenSwitcher'
                description = 'An abstract structure for JavaFX based applications for handling dialogs and switching between them.'
                url = 'https://steinbrecher.bayern/projects/mavenPackages.html#screenSwitcher'
                licenses {
                    license {
                        name = 'The Beer-Ware License (Revision 42)'
                    }
                }
                developers {
                    developer {
                        id = 'stefanHuber'
                        name = 'Stefan Huber'
                        email = 'stefan.huber.niedling@outlook.com'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/TrackerSB/ScreenSwitcher.git'
                    developerConnection = 'scm:git:ssh://github.com/TrackerSB/ScreenSwitcher.git'
                    url = 'https://github.com/TrackerSB/ScreenSwitcher'
                }
            }
            from components.java
        }
    }
}

signing {
    useGpgCmd()
    sign publishing.publications.mavenScreenSwitcher
}