GradleMongoPlugin/build.gradle at master · YouTechnology/GradleMongoPlugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
apply plugin: 'groovy'
apply plugin: 'idea'
apply plugin: 'eclipse'
apply plugin: 'maven'
apply plugin: 'signing'

archivesBaseName = 'gradle-mongo-plugin'
group = 'com.sourcemuse.gradle.plugin'
version = '0.7.0-SNAPSHOT'

sourceCompatibility = 1.7
targetCompatibility = 1.7

repositories {
    mavenCentral()
}

dependencies {
    compile gradleApi()
    compile 'de.flapdoodle.embed:de.flapdoodle.embed.mongo:1.47.0'

    testCompile files('libs/gradle-test-kit.jar')
    testCompile 'org.spockframework:spock-core:0.7-groovy-2.0', {
        exclude module: 'groovy-all'
    }
    testCompile 'org.mongodb:mongo-java-driver:2.12.2'
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from 'build/docs/javadoc'
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives jar
    archives javadocJar
    archives sourcesJar
}

signing {
    required { !version.endsWith('SNAPSHOT') && gradle.taskGraph.hasTask("uploadArchives") }
    sign configurations.archives
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { signing.signPom(it) }

            repository(url: 'https://oss.sonatype.org/service/local/staging/deploy/maven2/') {
                authentication(userName: getSonatypeUsername(), password: getSonatypePassword())
            }

            snapshotRepository(url: 'https://oss.sonatype.org/content/repositories/snapshots/') {
                authentication(userName: getSonatypeUsername(), password: getSonatypePassword())
            }

            pom.project {
                name 'Gradle Mongo Plugin'
                packaging jar
                description 'Gradle plugin for managing a local instance of MongoDb'
                url 'https://github.com/sourcemuse/GradleMongoPlugin'

                scm {
                    url 'scm:git@github.com:sourcemuse/GradleMongoPlugin.git'
                    connection 'scm:git@github.com:sourcemuse/GradleMongoPlugin.git'
                    developerConnection 'scm:git@github.com:sourcemuse/GradleMongoPlugin.git'
                }

                licenses {
                    license {
                        name 'The Apache Software License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        distribution 'repo'
                    }
                }

                developers {
                    developer {
                        name 'Mashooq Badar'
                    }
                    developer {
                        name 'Robert Taylor'
                    }
                }
            }
        }
    }
}

String getSonatypeUsername() {
    properties['sonatypeUsername'] ?: 'username'
}

String getSonatypePassword() {
    properties['sonatypePassword'] ?: 'password'
}