VirtualApp/AppConfig.gradle at master · chenguangming/VirtualApp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
allprojects {
    repositories {
        maven { url 'https://jitpack.io' }
        google()
        mavenCentral()
        maven {
            url 'https://maven.aliyun.com/nexus/content/groups/public/'
        }
        maven {
            url 'https://maven.aliyun.com/nexus/content/repositories/jcenter'
        }
    }
}

subprojects {

    afterEvaluate {
        def isAndroidProject = project.plugins.hasPlugin('android')
        def isLibraryProject = project.plugins.hasPlugin('android-library')

        if (isAndroidProject || isLibraryProject) {
            android {
                compileSdkVersion 33
                //buildToolsVersion '30.0.1'

                compileOptions {
                    sourceCompatibility JavaVersion.VERSION_1_8
                    targetCompatibility JavaVersion.VERSION_1_8
                }

                if (new File(projectDir, "src/main/cpp/CMakeLists.txt").exists()) {
                    externalNativeBuild {
                        cmake {
                            path "src/main/cpp/CMakeLists.txt"
                        }
                    }
                }

                defaultConfig {
                    minSdkVersion 21
                    //noinspection OldTargetApi
                    targetSdkVersion 26

                    versionCode rootProject.ext.VA_VERSION_CODE
                    versionName rootProject.ext.VA_VERSION
                }

                lintOptions {
                    checkReleaseBuilds false
                    abortOnError false
                }
            }
        }

        if (isAndroidProject) {
            android {
                signingConfigs {
                    va {
                        storeFile       file(rootProject.ext.signing_storeFile)
                        storePassword   rootProject.ext.signing_storePassword
                        keyAlias        rootProject.ext.signing_keyAlias
                        keyPassword     rootProject.ext.signing_keyPassword
                    }
                }

                buildTypes {
                    release {
                        signingConfig signingConfigs.va
                        minifyEnabled true
                        shrinkResources true
                        zipAlignEnabled true
                        proguardFiles getDefaultProguardFile('proguard-android.txt'), "${rootProject.rootDir}/proguard/proguard-rules.pro", "proguard-rules.pro"
                    }

                    debug {
                        signingConfig release.signingConfig
                        crunchPngs false //关闭crunchPng优化
                        minifyEnabled false

                        //minifyEnabled true    //minifyEnabled为true的作用：启用代码混淆、压缩APK
                        //shrinkResources true   //shrinkResources为true用来开启删除无用资源
                        //zipAlignEnabled true   //不开启ZipAlign优化

                        proguardFiles getDefaultProguardFile('proguard-android.txt'), "${rootProject.rootDir}/proguard/proguard-rules.pro", "proguard-rules.pro"
                    }
                }
            }
        }
    }
}