[FEATURE]: JS messages and errors should be distinguishable from regular messages

[mlipok]

What feature would you like, or what problem are you facing?

JS messages and errors should be distinguishable from regular messages

What's your proposed solution?

to work on it

Screenshots

No response

Do you want to work on this issue/improvement?

Maybe

Any additional context?

https://github.com/mlipok/NetWebView2Lib/blob/7255dd85ae93e7fd0ad08457d964532ac5d6923b/examples/014-pdfJS-Static_PDF_Viewer.au3#L171

https://github.com/mlipok/NetWebView2Lib/blob/9be6e8011acfdab48584b85f92ddfa7bd383d316/NetWebView2Lib.au3#L1391-L1453

[ioa747]

Hi @mlipok,

After analyzing the current behavior of the Bridge and the logging system, I have a "package" proposal that solves the noise issue while ensuring we never miss critical errors.

1. The "Force Log" Logic (Small but Mighty change)
   Instead of adding more parameters to __NetWebView2_Log, we can introduce a Priority Prefix (!!!). If a log string starts with !!!, it bypasses the $_g_bNetWebView2_DebugInfo check.

Updated __NetWebView2_Log:

Func __NetWebView2_Log($s_ScriptLineNumber, $sString, $iErrorNoLineNo = 1, $iError = @error, $iExtended = @extended)
    Local $bForceLog = (StringLeft($sString, 3) == "!!!")
    If Not $_g_bNetWebView2_DebugInfo And Not $bForceLog Then Return SetError($iError, $iExtended, 0)
	If $iErrorNoLineNo = 1 Then
		If $iError Then
			$sString = "! ( NetWebView2Lib UDF : SLN=" & $s_ScriptLineNumber & ", @error=" & $iError & ", @extended=" & $iExtended & " ) :: " & $sString
		Else
			$sString = "+> ( NetWebView2Lib UDF : SLN=" & $s_ScriptLineNumber & " ) :: " & $sString
		EndIf
	EndIf
    Local $iReturn = ConsoleWrite($sString & @CRLF)
	Return SetError($iError, $iExtended, $iReturn)
EndFunc

2. Refactoring __NetWebView2_JSEvents__OnMessageReceived
   We should strip the Core Handler of any "User-level" logic (like COM_TEST or JSON_CLICKED). The Core should only act as a System Monitor.

Proposed Logic:

Identify Errors: Check if the message is an Error (JSON or Legacy).

Conditional Log: - If it's an Error, use the !!! prefix to ensure visibility.

For everything else, log normally (it will only show if Debug is ON).

Ignore User Data: If the message is not a system error, let the Core Handler exit and let the User's Bridge Handler manage it.

Example of Cleaned Internal Handler:

Volatile Func __NetWebView2_JSEvents__OnMessageReceived($oWebV2M, $hGUI, $sMsg)
	Local Const $s_Prefix = "[JSEvents__OnMessageReceived]: GUI:" & $hGUI
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError, $oWebV2M

    Local $sFirstChar = StringLeft($sMsg, 1)
    Local $bIsError = False

    ; Quick check for Errors
    If $sFirstChar = "{" Or $sFirstChar = "[" Then
        If StringInStr($sMsg, '"type":"error"') Then $bIsError = True
    Else
        If StringLeft($sMsg, 6) == "ERROR|" Or StringLeft($sMsg, 10) == "NAV_ERROR|" Then $bIsError = True
    EndIf

    ; Logic: Errors are Forced (!!!), regular messages follow Global Debug flag
    If $bIsError Then
		__NetWebView2_Log(@ScriptLineNumber, "!!! " & $s_Prefix & " JSEvents ERROR: " & $sMsg, 1)
    ElseIf $_g_bNetWebView2_DebugInfo Then
		__NetWebView2_Log(@ScriptLineNumber, $s_Prefix  & " JSEvents ERROR: " & $sMsg, 1)
    EndIf

    ; REMOVED: COM_TEST, JSON_CLICKED, etc. (They belong to the User's Bridge Handler)
EndFunc

Users won't see "Title Changed" or "Metadata" logs during normal operation (Debug=False).
JS Errors will always Write in the console.

What do you think about?